Customizing the Kaplan-Meier Survival Plot

The second way to approach this problem requires you to modify the data object and use the ODS document. The first things you must do are to open an ODS document, save the results of the PROC LIFETEST analysis, save the data object that underlies the graph into a SAS data set, and close the ODS document. The following code illustrates:

ods document name=MyDoc (write);
proc lifetest data=sashelp.BMT plots=survival(cb=hw atrisk(outside maxlen=13));
   ods output survivalplot=sp;
   time T * Status(0);
   strata Group;
run;
ods document close;

The ODS document contains all the tables, graphs, titles, notes, and other components of the output. The following step lists the contents of the ODS document:

proc document name=MyDoc;
   list / levels=all;
quit;

The contents are displayed in Figure 42.

In the following step, you copy and paste the ODS document path for the survival plot into the OBDYNAM statement to create an ODS output data set that contains all the dynamic variables for the survival plot:

proc document name=MyDoc;
   ods output dynamics=dynamics;
   obdynam \Lifetest#1\SurvivalPlot#1;
quit;

The dynamic variables and their values are displayed in Figure 43.^[24]

You can use a DATA step as follows to generate a PROC SGRENDER statement; specify the ODS output data set, the template, and the format; and specify the names and values of all the dynamic variables:

data _null_;
   set dynamics(where=(label1 ne '___NOBS___')) end=eof;
   if _n_ = 1 then
      call execute('proc sgrender data=sp
                    template=Stat.Lifetest.Graphics.ProductLimitSurvival2;
                    format stratum $dfmt.;
                    dynamic');
   if cvalue1 ne ' ' then
      call execute(catx(' ', label1, '=',
                   ifc(n(nvalue1), cvalue1, quote(trim(cvalue1)))));
   if eof then call execute('; run;');
run;

This DATA step generates and executes a PROC SGRENDER step that creates the graph. The DATA step uses a series of CALL EXECUTE statements to populate the list of dynamic variables. The DATA step generates and submits to SAS the following code (which has been reformatted for display here):

proc sgrender data=sp
   template=Stat.Lifetest.Graphics.ProductLimitSurvival2;
   format stratum $dfmt.;
   dynamic
      NSTRATA = 3
      PLOTHW = 1
      PLOTEP = 0
      PLOTCL = 0
      PLOTCENSORED = 1
      Transparency = 0.7
      PLOTTEST = 0
      METHOD = "Product-Limit"
      ROWWEIGHTS = "PREFERRED"
      XNAME = "T"
      LABELHW = "95% Hall-Wellner Band"
      SECONDTITLE = "With Number of Subjects at Risk and 95% Hall-Wellner Bands"
      GROUPNAME = "Disease Group"
      CLASSATRISK = "Stratum";
run;

The survival plot, which now contains the long dashes, is displayed in Figure 44.

Figure 44: Unicode in the Legend

This example shows that you can save the data object and dynamic variables into SAS data sets. Then you can apply a format to the Stratum variable as you create the graph from those data sets. The advantage of this approach is that it provides full flexibility. For example, you can use it with multiple strata variables.