FASTLOAD= LIBNAME Statement Option

Default Behavior for Data Transfer

When you set FASTLOAD=YES, you specify that SAS should use the TPT API to efficiently load data into an empty Teradata table. SAS/ACCESS creates the target table. For more information, see Maximizing Teradata Load and Read Performance.

Best Practice for Specifying FASTLOAD=

You can specify FASTLOAD= using a data set option or LIBNAME option. Use care with the FASTLOAD= LIBNAME option (rather than the data set option). Any time that you insert data from SAS into Teradata tables, the TPT FastLoad utility is used. This uses Teradata utility slots and might also cause other load jobs to fail.

Specifying the FASTLOAD= LIBNAME option on a SAS library hides it from users. In a BI environment, it can be difficult to tell whether the option is specified. If you are setting up SAS libraries that are used only by ETL jobs, then it might be acceptable to use the LIBNAME option.

Teradata on AIX: Beginning with the August 2024 update for SAS/ACCESS on SAS 9.4M8 and with the October 2024 update for SAS/ACCESS on SAS 9.4M7, setting FASTLOAD=NO is ignored. SAS uses the Teradata Parallel Transporter API to load data to Teradata. For more information, see SAS Note 70928 - SAS/ACCESS Interface to Teradata support for Teradata Tools and Utilities (TTU) 17.xx and later in AIX environments.

libname mytera TERADATA server=teraserv user=bob pw=bob1;
/* Create and load a table using a DATA step. SAS numeric is */
/*   forced to be an INTEGER.                                */ 
data mytera.table0 (FASTLOAD=YES DBTYPE= (x= INTEGER)); 
   do x = 1 to 1000000; 
       output; 
   end; run;

/* Load an existing table using PROC APPEND. The table must meet */
/* certain requirements.                                         */ 
PROC SQL; 
   CONNECT TO TERADATA (USER=bob PW=bob1 SERVER=tera5500); 
   EXECUTE (DROP TABLE loadThisTable) by TERADATA; 
   EXECUTE (COMMIT) BY TERADATA; 
   EXECUTE (CREATE MULTISET TABLE loadThisTable ( a INTEGER , b CHAR(10)) 
     PRIMARY INDEX (a)) by TERADATA; 
   EXECUTE (COMMIT) BY TERADATA; 
QUIT; 
DATA work.loadData; 
   FORMAT b $10.; 
   a = 1; 
     output;   
   b = 'One'; 
     output; 
   a = 2; 
     output;
   b = 'Two';
     output; 
   a = 3; 
     output;
   b = 'Three'; 
     output; 
RUN;

libname mytera teradata server=teraserv user=bob pw=bob1 FASTLOAD=YES;
PROC APPEND BASE=mytera.loadThisTable (BL_LOG=BOB_APPEND_ERR) 
     DATA=work.loadData; 
RUN;