The CAUSALGRAPH Procedure

(View the complete code for this example.)

This example illustrates how you can use the CAUSALGRAPH procedure to find an instrumental variable in a causal model. By using an instrumental variable, you can identify a causal effect even when there is unobserved confounding between a treatment variable and an outcome variable, which is a situation where the adjustment criterion might fail.

In Example 37.2, a causal model, adapted from Timmermann et al. (2017), is used to examine the relationship between maternal exposure to persistent perfluoroalkyl substances (PFAS) and breastfeeding duration among residents of the Faroe Islands. That example shows that you cannot construct an adjustment set to estimate the causal effect of the treatment variable PFAS on the outcome variable Duration. This is because there is confounding bias between the treatment and outcome variables that results from the unobserved variables HealthBehavior and PrevBF.

In many cases where there is unmeasured confounding, you can still estimate the causal effect if you are willing to assume that certain edges in the causal model have a particular parametric form. Then it might be possible to use an instrumental variable (Angrist, Imbens, and Rubin 1996; Imbens 2014). The following statements invoke PROC CAUSALGRAPH to list possible instrumental variables that you can use to estimate the causal effect:

proc causalgraph method=iv;
   model "Timm17HealthBehavior"
      Age ==> Parity PFAS Education,
      Parity ==> PrevBF Duration PFAS,
      PrevBF ==> PFAS Duration,
      PFAS ==> Duration,
      Education ==> Duration HealthBehavior Employment,
      HealthBehavior ==> PFAS Duration BMI Alcohol Smoking,
      Employment ==> HealthBehavior Duration,
      BMI Alcohol Smoking ==> Duration;
   identify PFAS ==> Duration;
   unmeasured PrevBF HealthBehavior;
run;

In the MODEL statement, you specify the same causal model as in Example 37.2. In the IDENTIFY statement, you specify that the causal effect of the variable PFAS on the variable Duration is of interest. By specifying the METHOD=IV option in the PROC CAUSALGRAPH statement, you use an instrumental variable (or a conditional instrumental variable) to identify the causal effect. The UNMEASURED statement specifies that the variables PrevBF and HealthBehavior are not observed and thus cannot be included as an instrument or in any conditional set.

As shown in the table in Output 37.5.1, there is one variable that you can use as an instrument to identify the causal effect of PFAS on Duration. The variable Age is a conditional instrument. That is, Age becomes an instrument after its association with the outcome variable Duration is blocked by conditioning on the five variables shown in Output 37.5.1. If an instrumental variable is a classical instrument (that is, you can use the variable as an instrument without conditioning on any other variables), then the procedure prints an empty conditioning set for that variable.

The conditional sets that are produced in constructing an instrument might not be minimal. For instance, the following test shows that you can use Age as a conditional instrument if you adjustment for only the variables Education and Parity:

proc causalgraph method=iv;
   model "Timm17HealthBehavior"
      Age ==> Parity PFAS Education,
      Parity ==> PrevBF Duration PFAS,
      PrevBF ==> PFAS Duration,
      PFAS ==> Duration,
      Education ==> Duration HealthBehavior Employment,
      HealthBehavior ==> PFAS Duration BMI Alcohol Smoking,
      Employment ==> HealthBehavior Duration,
      BMI Alcohol Smoking ==> Duration;
   identify PFAS ==> Duration;
   unmeasured PrevBF HealthBehavior;
   testid "Minimal CIV" Age / conditional = (Education Parity);
run;

The model specification, the causal effect of interest, and the identification criterion are the same as those in the previous CAUSALGRAPH analysis in this example. What is new here is the inclusion of the TESTID statement. You want to investigate whether Age can serve as a conditional instrumental variable for the causal effect, where the conditioning variables are Education and Parity. This set of conditional variables is a proper subset of the proposed conditional variables in the previous analysis. As shown in Output 37.5.2, the value for the Valid column is "Yes," providing an affirmative answer to this investigation.