The CAUSALMED Procedure

(View the complete code for this example.)

This example continues the analysis of Example 38.1; it illustrates the use of the EVALUATE statement for computing controlled direct effects and mediation effects conditional on covariate values.

The following code includes three EVALUATE statements that assign different values for the mediator Motivation:

proc causalmed data=Cognitive;
   model    CogPerform  = Encourage | Motivation;
   mediator Motivation  = Encourage;
   covar    FamSize SocStatus;
   evaluate 'Default Mean Value of Mediator' Motivation=mean;
   evaluate 'High-Motivation Group' Motivation = 1(SD);
   evaluate 'Low-Motivation Group' Motivation = -1(SD);
run;

The labels, which are enclosed in quotation marks, distinguish the three EVALUATE statements and the output that they produce. The first EVALUATE statement specifies the level of the mediator Motivation as its mean. This happens to be the default level, so you should expect this statement to produce the same evaluation of causal effects that PROC CAUSALMED produces by default. Output 38.2.1 displays the causal mediation effects that are evaluated by default, and Output 38.2.2 displays the causal mediation effects that are evaluated for the mediator level in the first EVALUATE statement. Clearly, these two tables are identical.

There might be situations in which you want to evaluate the causal effects at other mediator levels. The second and third EVALUATE statements set the mediator level at one standard deviation above and below the mean, respectively. PROC CAUSALMED computes the sample mean and standard deviation (SD) for Motivation and then computes the levels of motivation as

These values of are then used to evaluate the various causal mediation effects, which are displayed in Output 38.2.3 and Output 38.2.4.

Output 38.2.3 and Output 38.2.4 show that the total effect remains the same in the two evaluations, as expected. Because the controlled direct effect is defined at a particular level of the mediator level (), it is not surprising that the two evaluations lead to different estimates of the controlled direct effect.

At one standard deviation above the mean of Motivation, the controlled direct effect is 4.34. This is higher than the controlled direct effect at one standard deviation below the mean, which is 4.02. The percentages of the total effect that are due to interaction also differ for the two levels of Motivation. One percentage is –2% and the other is 3%, although both are small and negligible.

You can also use the EVALUATE statement to evaluate causal mediation effects for particular target groups. The following EVALUATE statements estimate causal mediation effects for small families (FamSize=3) and large families (FamSize=7):

proc causalmed data=Cognitive;
   model    CogPerform  = Encourage | Motivation;
   mediator Motivation  = Encourage;
   covar    FamSize SocStatus;
   evaluate 'Small Families' FamSize=3;
   evaluate 'Large Families' FamSize=7;
run;

Output 38.2.5 and Output 38.2.6 display the corresponding effect summaries.

The patterns of all causal effects are similar for small families and large families. Small families appear to have a slightly higher total effect. For both groups, the percentage of the total effect that is due to the interaction between Encourage and Motivation is very small. For both groups, about 40% of the total effect is due to the mediation of Motivation.

The next set of EVALUATE statements estimate causal mediation effects for subjects whose social status (SocStatus) is high or low.

proc causalmed data=Cognitive;
   model    CogPerform  = Encourage | Motivation;
   mediator Motivation  = Encourage;
   covar    FamSize SocStatus;
   evaluate 'High Social Status' SocStatus=1(SD);
   evaluate 'Low Social Status'  SocStatus=-1(SD);
run;

Output 38.2.7 and Output 38.2.8 display the corresponding effect summaries.

Again, the patterns of all causal effects are similar for both groups. The high social status group appears to have a slightly higher total effect.

You can also combine the specifications of covariates to evaluate specific causal mediation effects. In the following EVALUATE statements, subjects are defined by a combination of levels of FamSize and SocStatus:

proc causalmed data=Cognitive;
   model    CogPerform  = Encourage | Motivation;
   mediator Motivation  = Encourage;
   covar    FamSize SocStatus;
   evaluate 'Most Favorable Environment'  FamSize=-.5(SD) SocStatus=1(SD);
   evaluate 'Least Favorable Environment' FamSize=.5(SD) SocStatus=-1(SD);
run;

The effects labeled 'Most Favorable Environment' are defined by FamSize at 0.5 standard deviation below the mean family size and SocStatus at 1 standard deviation above the mean social status rating. The effects labeled 'Least Favorable Environment' are defined by FamSize at 0.5 standard deviation above the mean family size and SocStatus at 1 standard deviation below the mean social status rating.

Output 38.2.9 and Output 38.2.10 display the corresponding effect summaries.

The patterns of all causal mediation effects are similar for the two groups. The total effect for 'Most Favorable Environment' is slightly larger than the total effect for 'Least Favorable Environment'.

Together, these evaluations show that about 40% of the effect of parental encouragement on cognitive development is mediated by children’s learning motivation. The interaction effect of parental encouragement and children’s learning motivation is small. And more importantly, these conclusions appear to hold for different family sizes and levels of social status.

For more information about setting the covariate levels, see the EVALUATE statement and the section Evaluating Causal Mediation Effects.