Quantile Regression Modeling Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts. A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

The following example is modeled on the example in the section "Getting Started: QUANTSELECT Procedure" in the SAS/STAT User's Guide. The Sashelp.baseball data set contains salary and performance information for Major League Baseball (MLB) players, excluding pitchers, who played in at least one game in both the 1986 and 1987 seasons. The salaries (Time Inc. 1987) are for the 1987 season, and the performance measures are for the 1986 season (Reichler 1987).

The following statements display the variables in the data set. Output 18.1.1 shows the results.

proc contents varnum data=sashelp.baseball;
   ods select position;
run;

You can load the Sashelp.Baseball data set into your CAS session by naming your CAS engine libref in the first statement of the following DATA step:

data mycas.baseball;
   set sashelp.baseball;
run;

These statements assume that your CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

Suppose you want to investigate how the MLB players’ salaries for the 1987 season depend on performance measures for the players’ previous season and MLB career. You might worry that some players who are outliers could dominate your least squares analysis. To address this concern, you can use the following statements to obtain a median regression model, which is equivalent to the 50th conditional percentile (the quantile regression model at quantile level 0.5):

proc cas;
   action quantreg.quantreg/
      table={name='baseball'},
      class={'league','division'},
      model={depvars='Salary',
             effects={'nAtBat', 'nHits', 'nHome', 'nRuns',
                      'nRBI', 'nBB', 'yrMajor', 'crAtBat',
                      'crHits', 'crHome', 'crRuns', 'crRbi',
                      'crBB', 'league', 'division', 'nOuts',
                      'nAssts', 'nError'}};
run;

If you do not use the selection parameter, the quantreg action fits the full model that is specified by the model parameter without any effect selection.

Output 18.1.2 displays the data source and the response variable.

Output 18.1.3 displays information about the number of observations, class levels, and dimensions.

The "Number of Observations" table in Output 18.1.3 shows that, of the 322 observations, the quantreg action uses only 263 observations for model fitting (and ignores 59 incomplete observations).

The "Class Level Information" table in Output 18.1.3 shows level information for two classification effects that the class parameter identifies: League and Division. League has two levels: American and National. Division also has two levels: East and West.

The "Dimensions" table in Output 18.1.3 shows that the model parameter identifies 19 effects for model fitting besides the intercept effect. Because the 19 effects include two classification effects and each level of a classification effect corresponds to a parameter, the 19 effects contain a total of 21 parameters.

The "Fit Statistics" table in Output 18.1.4 shows the values of model fitting criteria for the fitted median model. For more information about model fitting criteria for quantile regression, see the section Details.

The "Parameter Estimates" table in Output 18.1.5 shows the parameter estimates of the fitted median model. Among the 19 effective parameters whose degrees of freedom are not zero, the fitted model contains 13 insignificant parameters whose 95% confidence intervals cover zeros. Because more than half of the 19 effective parameters are insignificant, you might worry that the model is overfitted.

It is well known that both overfitting and underfitting harm the prediction performance of a model. You can prevent overfitting and underfitting by using an effect-selection method. The following statements apply the forward selection method and the SL (significance level) criterion to choose a parsimonious model for the baseball data table:

proc cas;
   action quantreg.quantreg/
      table={name='baseball'},
      class={'league','division'},
      model={depvars='Salary',
             effects={'nAtBat', 'nHits', 'nHome', 'nRuns',
                      'nRBI', 'nBB', 'yrMajor', 'crAtBat',
                      'crHits', 'crHome', 'crRuns', 'crRbi',
                      'crBB', 'league', 'division', 'nOuts',
                      'nAssts', 'nError'},
             stb=1,
             clb=1},
      selection={method='forward', select='sl', sle=0.1};
run;

The stb subparameter in the model parameter requests the standardized parameter estimates. The clb subparameter in the model parameter requests 95% confidence limits for the parameter estimates. The sle=0.1 subparameter in the selection parameter specifies the significance level for entry. A candidate effect can enter the model at a certain selection step only if the following conditions are met:

The "Selection Information" table in Output 18.1.6 provides details about the method and criteria used to perform the model selection. The requested selection method is the forward selection method, in which the decisions about what effects to add at any step and when to terminate the selection are both based on the significance level criterion.

Each row in the "Selection Summary" table in Output 18.1.7 shows the effect that enters the model at the corresponding step of the effect selection process together with its p-value for adding the effect into the model at that step.

The "Stop Reason" and "Selection Reason" tables in Output 18.1.8 indicate that effect selection stopped because no candidate for entry was significant at the 0.1 level after step 8. The "Selected Effects" table in Output 18.1.8 lists the effects that are included in the selected model.

The "Fit Statistics" and "Parameter Estimates" tables in Output 18.1.9 give details of the final selected model. You can see that all nine effective parameters (excluding Division West) are significant at the 5% significance level, corresponding to the 95% confidence limits.

Like the sample median, a median regression model is robust to extreme observations, because it depends only on a small middle subset of all the observations in the data table. However, it is less representative of the entire conditional distribution of the response variable. You might want to further investigate the mycas.baseball data table at other quantile levels. The following statements select quantile regression models at the quantile levels 0.1 and 0.9, which correspond to the 10% and 90% conditional percentiles of the players’ salaries:

proc cas;
   action quantreg.quantreg/
      table={name='baseball'},
      alpha=0.1,
      class={'league','division'},
      model={depvars='Salary',
             effects={'nAtBat', 'nHits', 'nHome', 'nRuns',
                      'nRBI', 'nBB', 'yrMajor', 'crAtBat',
                      'crHits', 'crHome', 'crRuns', 'crRbi',
                      'crBB', 'league', 'division', 'nOuts',
                      'nAssts', 'nError'},
             quantile={0.1, 0.9},
             stb=1,
             clb=1},
      selection={method='backward', select='sl', sle=0.1};
run;

The alpha=0.1 parameter in the quantreg.quantreg action specifies the significance level to be 0.1. Combined with the clb subparameter in the model parameter, the alpha=0.1 parameter requests 90% confidence limits for parameter estimates. The quantile={0.1, 0.9} subparameter in the model parameter specifies two quantile levels, 0.1 and 0.9, for fitting quantile regression models. The method=’backward’ subparameter in the selection parameter specifies the backward elimination method for effect selection.

Output 18.1.10 and Output 18.1.11 display the "Selected Effects" and "Parameter Estimates" tables at the quantile levels 0.1 and 0.9, respectively. Note, for example, that League is selected for its very large effect on how much the high-salary players were paid, but it apparently had a negligible effect on how much the low-salary players made.