The CNTSELECT Procedure

This example shows how to use the CNTSELECT procedure to estimate a zero-inflated Poisson model with a classification variable Group that has two levels. The following DATA step generates 10,000 replicates from the zero-inflated Poisson (ZIP) model. The first 5,000 replicates belong to the first group, and the second 5,000 replicates belong to the second group. The model contains seven variables and three variables that correspond to the zero-inflated process.

    data simulate;
       call streaminit(12345);
       array vars x1-x7;
       array zero_vars z1-z3;

       array parms{7}  (.3 .4 .2 .4 -.3 -.5 -.3);
       array zero_parms{3} (-.6 .3 .2);

       intercept=0.5;
       group=1;
       z_intercept=-1;
       theta=0.5;

       do i=1 to 10000;
          sum_xb=0;
          sum_gz=0;
          if i>5000 then do;
             intercept=2;
             group=2;
          end;
          do j=1 to 7;
             vars[j]=rand('NORMAL',0,1);
             sum_xb=sum_xb+parms[j]*vars[j];
          end;
          mu=exp(intercept+sum_xb);
          y_p=rand('POISSON', mu);

          do j=1 to 3;
             zero_vars[j]=rand('NORMAL',0,1);
             sum_gz = sum_gz+zero_parms[j]*zero_vars[j];
          end;
          z_gamma = z_intercept+sum_gz;
          pzero = cdf('LOGISTIC',z_gamma);
          cut=rand('UNIFORM');
          if cut<pzero then y_p=0;
          output;
       end;
    keep y_p group x1-x7 z1-z3;
    run;

You can load the simulate data set into your CAS session by naming your CAS engine libref in the first statement of the following DATA step:

data mycas.simulate;
   set simulate;
run;

These statements assume that your CAS engine libref is named mycas, but you can substitute any appropriately defined libref.

The following statements estimate a zero-inflated Poisson model with the classification variable Group:

 proc cntselect data=mycas.simulate dist=zip;
    class group;
    model y_p=group x1-x7;
    zeromodel y_p ~ z1-z3;
 run;

Output 8.1.1 shows the results for the zero-inflated Poisson model.

The "Class Level Information" table shows that the classification variable Group has two levels. The "Model Fit Summary" table shows detailed information about the model and indicates that all 10,000 observations were used to fit the model. All parameter estimates in the "Parameter Estimates" table are highly significant and correspond to their theoretical values set during the data generating process.