The OPTLP Procedure

Getting Started: OPTLP Procedure

The following example illustrates how you can use the OPTLP procedure to solve linear programs. Suppose you want to solve the following problem:

The corresponding MPS-format SAS data set is as follows:

data example;
   input field1 $ field2 $ field3 $ field4 field5 $ field6;
   datalines;
NAME        .      EXAMPLE   .    .     .
ROWS        .      .         .    .     .
N           COST   .         .    .     .
G           R1     .         .    .     .
L           R2     .         .    .     .
L           R3     .         .    .     .
COLUMNS     .      .         .    .     .
.           X1     COST      2    R2    1
.           X1     R3        1    .     .
.           X2     COST     -3    R1   -2
.           X2     R2        1    R3    2
.           X3     COST     -4    R1   -3
.           X3     R2        2    R3    3
RHS         .      .         .    .     .
.           RHS    R1       -5    R2    4
.           RHS    R3        7    .     .
ENDATA      .      .         .    .     .
;

You can also create this data set from an MPS-format flat file (examp.mps) by using the following SAS macro:

%mps2sasd(mpsfile = "examp.mps", outdata = example);

Note: The SAS macro %MPS2SASD is provided in SAS Optimization software. See Converting an MPS/QPS-Format File: %MPS2SASD for details.

To make the created data set available on the CAS server, you need to upload it. At the same time, you also add an _id_ column to ensure that the MPS reader can read the file in the correct order even if it is distributed across several machines and hence loses the original ordering. For more information about the MPS-format, see Chapter 8, The MPS-Format Data Table.

data mycas.example;
   set example;
   _id_ = _n_;
run;

Alternatively, you can create the MPS data table directly in CAS and include the _id_ column in the datalines input.

You can use the following statement to call the OPTLP procedure:

title1 'The OPTLP Procedure';
proc optlp data = mycas.example
  objsense  = min
  presolver = automatic
  algorithm = primal
  primalout = mycas.expout
  dualout   = mycas.exdout;
run;

Note: The "N" designation for "COST" in the rows section of the data table example also specifies a minimization problem. See the section ROWS Section for details.

The optimal primal and dual solutions are stored in the data tables expout and exdout, respectively, and are displayed in Figure 1.

title2 'Primal Solution';
proc print data=mycas.expout label;
run;

title2 'Dual Solution';
proc print data=mycas.exdout label;
run;

Figure 1: Primal and Dual Solution Output

The OPTLP Procedure

Primal Solution

Obs	Objective Function ID	RHS ID	Variable Name	Variable Type	Objective Coefficient	Upper Bound	Variable Value	Variable Status	Reduced Cost
1	COST	RHS	X1	N	2	1.7977E308	0.0	L	2.0
2	COST	RHS	X2	N	-3	1.7977E308	2.5	B	0.0
3	COST	RHS	X3	N	-4	1.7977E308	0.0	L	0.5

The OPTLP Procedure

Dual Solution

Obs	Objective Function ID	RHS ID	Constraint Name	Constraint Type	Constraint RHS	Constraint Lower Bound	Constraint Upper Bound	Dual Solution	Constraint Status	Constraint Activity
1	COST	RHS	R1	G	-5	.	.	1.5	U	-5.0
2	COST	RHS	R2	L	4	.	.	0.0	B	2.5
3	COST	RHS	R3	L	7	.	.	0.0	B	5.0

For details about the type and status codes displayed for variables and constraints, see the section Data Input and Output.

Last updated: April 05, 2021