Optimization Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 3, Shared Concepts (SAS Optimization: Mathematical Optimization Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example shows different ways to specify user-provided tuning parameters, the parameter tuning range, and the initial tuning value in the tuningparameters parameter. The example also shows how to change the value of a default parameter in the milpparameters parameter. When you can specify the USER value in the optionmode subparameter in the tunerparameters parameter, then in the tuningparameters parameter you define the parameters, their ranges, and their initial values. The basic rule is that if you specify only a parameter name, the tuner action goes through all the valid values and uses the default value as the initial value. If you do not specify the initial parameter, the tuner action uses the default value or the first value specified in the values parameter as the initial value when the default value is not in the values parameter range.

If you want to specify a solveMilp action’s parameter that is not being tuned to a nondefault value, you can do so in the milpparameters parameter.

You can also output a detailed tuning results table by specifying the data table in the tunerout subparameter in the tunerparameters parameter. The table contains parameter settings and solution summaries of different problems under different parameter settings.

The following code calls the tuner action to tune the data tables air04 and air05 by using six tuning parameters with different ranges and initial values:

libname caslib cas;
filename air04 "path-to-air04.mps file";
filename air05 "path-to-air05.mps file";

%mps2sasd(mpsfile=air04, outdata=caslib.air04);
%mps2sasd(mpsfile=air05, outdata=caslib.air05);

proc cas;
loadactionset 'optimization';
tuner /
   instances={{data='air04'}, {data='air05'}}
   tuningParameters={
      {option='presolver', values={'basic', 'aggressive', 'none'}, initial='none'},
      {option='strongiter', values={-1, 100. 1000, 10000}, initial=-1},
      {option='cutstrategy'},
      'probe',
      {option='symmetry', initial='none'},
      {option='cutgub', values={'none','moderate'}}
   }
   milpParameters={conflictSearch='automatic', cutGub='moderate', maxtime=100}
   tunerParameters={maxtime=400, nthreads=4, optionmode='user',
      tunerOut={name='tout', replace=true}}
;
run;
quit;

proc print data=caslib.tout(obs=16); run;

Output 2.16.1 shows partial results of the data table specified in the tunerout subparameter. This table has a detailed summary of the results of each problem under different parameter configurations. The RANK=0 row shows the result of the initial run on each tuning problem. The rest of the rows are sorted according to the performance measure specified in the goal subparameter.