The CQLIM Procedure

This example uses the CQLIM procedure to process a small data table in the distributed computing environment.

The following DATA step generates a data set that contains 1,000 observations from a censored model. The model contains eight variables.

data bayes_ex;
   call streaminit(12345);
   array vars x1-x7;
   array parms{7} (3 4 2 4 -3 -5 -3);
   intercept1 = 0;
   intercept2 = 4;
   intercept3 = 10;
   do i = 1 to 1000;
      sum_xb = 0;
      do j = 1 to 7;
         vars[j] = rand('NORMAL', 0, 1);
         sum_xb = sum_xb + parms[j] * vars[j];
      end;
      g = rand('NORMAL', 0, 1);
      if g <  -0.5 then intercept = intercept1;
      if g >= -0.5 then intercept = intercept2;
      if g >   0.5 then intercept = intercept3;
      y = intercept + sum_xb + 10 * rand('NORMAL', 0, 1);
      if y > 400 then y = 400;
      if y < 0   then y = 0;
      if g <  -0.5 then group = 0;
      if g >= -0.5 then group = 1;
      if g >   0.5 then group = 2;
      output;
   end;
   keep y x1-x7 group;
run;

You can load the bayes_ex data set into your CAS session by naming your CAS engine libref in the first statement of the following DATA step:

data mycas.bayes_ex;
   set bayes_ex;
run;

These statements assume that your CAS engine libref is named mycas, but you can substitute any appropriately defined libref.

The following statements estimate a censored model by using Bayesian methods. Note that the BAYES statement controls the settings for the MCMC sampler and determines which Bayesian output is produced. The NCHAIN= option controls the number of Markov chains, and the NSAMPLE= option controls the size of the posterior sample per chain. The PRIOR statements set the prior distributions for the parameters.

proc cqlim data = mycas.bayes_ex;
   class group;
   model y = x1-x7 group / censored(lb = 0 ub = 400);
   bayes priorsummary(shownames) seed = 72342 nsample = 10000 nchain = 4
         sampler = rwm(ntune = 100 ntunestage = 20);
   prior intercept ~ normal(mean = 0, sd = 100);
   prior x1-x5 ~ normal(mean = 0, sd = 10);
   prior x6 ~ t(loc = 0, scale = 10, df = 3, lower = 0);
   prior group_0 ~ normal(mean = -4, var = 100);
   prior _sigma ~ normal(mean = 0, sd = 100);
run;

Output 11.3.1 shows the Bayesian estimation results for the censored model. The "Prior Summary" table shows detailed information about prior distributions for the parameters in the model. The "Posterior Summaries" table contains two point estimates of the parameters from the posterior samples: the posterior mean and the posterior median (50th percentile). The "MCMC Diagnostics Summaries" table contains basic convergence diagnostics to check whether the Markov chain has converged and whether the sample size is sufficient.