The SEVSELECT Procedure

The Tweedie distribution is often used in the insurance industry to explain the influence of regression effects on the distribution of losses. PROC SEVSELECT provides a predefined scaled Tweedie distribution (STWEEDIE) that enables you to model the influence of regression effects on the scale parameter. The scale regression model has its own advantages such as the ability to easily account for inflation effects. This example illustrates how that model can be used to evaluate the influence of regression effects on the mean of the Tweedie distribution, which is useful in problems such rate-making and pure premium modeling.

Assume a Tweedie process, whose mean is affected by k regression effects , , as follows,

where represents the base value of the mean (you can think of as , where is the intercept). This model for the mean is identical to the popular generalized linear model for the mean with a logarithmic link function.

More interestingly, it parallels the model used by PROC SEVSELECT for the scale parameter ,

where represents the base value of the scale parameter. As described in the section Tweedie Distributions, for the parameter range , the mean of the Tweedie distribution is given by

where is the Poisson mean parameter of the scaled Tweedie distribution. This relationship enables you to use the scale regression model to infer the influence of regression effects on the mean of the distribution.

Let the data set Work.Test_Sevtw contain a sample generated from a Tweedie distribution with dispersion parameter , index parameter , and the mean parameter that is affected by three regression variables x1, x2, and x3 as follows:

Thus, the population values of regression parameters are , , , and .

You following DATA step generates a sample of the Tweedie distribution:

/*--- Simulate a Tweedie sample that is affected by regressors ---*/
%let samplesize=300;
data test_sevtw(keep=y x1-x3
                label='A Tweedie Sample Affected by Regressors');
   array x{*} x1-x3;
   array b{4} _TEMPORARY_ (5 0.25 -1 3);
   call streaminit(45678);
   label y='Response Influenced by Regressors';

   Phi = 0.5;
   P = 1.75;
   do n = 1 to &samplesize;
      Mu = 0;
      do i = 1 to dim(x);
         x(i) = rand('UNIFORM');
         Mu = Mu + b(i+1) * x(i);
      end;
      Mu = b(1) * exp(Mu); /* b(1) is base value of mean */

      cdf = rand('UNIFORM');
      y = quantile('TWEEDIE', cdf, P, Mu, Phi);
      output;
   end;
run;

The following DATA step loads the data set Work.Test_sevtw into a data table in your CAS session that is associated with the mycas CAS engine libref. The DATA step assumes that your CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.test_sevtw;
   set test_sevtw;
run;

The following PROC SEVSELECT step uses the sample in mycas.Test_Sevtw data table to estimate the parameters of the scale regression model for the predefined scaled Tweedie distribution (STWEEDIE) with the dual quasi-Newton (QUANEW) optimization technique:

/*--- Fit the scale parameter version of the Tweedie distribution ---*/
proc sevselect data=mycas.test_sevtw outest=mycas.estw covout print=all;
   loss y;
   scalemodel x1-x3;

   dist stweedie;
   nloptions tech=quanew;
run;

The dual quasi-Newton technique is used because it requires only the first-order derivatives of the objective function, and it is harder to compute reasonably accurate estimates of the second-order derivatives of Tweedie distribution’s PDF with respect to the parameters.

Some of the key results that PROC SEVSELECT prepares are shown in Output 23.3.1 and Output 23.3.2. The model information and the convergence results are shown in Output 23.3.1.

The final parameter estimates of the STWEEDIE regression model are shown in Output 23.3.2. The estimate that is reported for the parameter Theta is the estimate of the base value . The estimates of regression coefficients , , and are indicated by the rows of x1, x2, and x3, respectively.

If your goal is to explain the influence of regression effects on the scale parameter, then the output displayed in Output 23.3.2 is sufficient. But, if you want to compute the influence of regression effects on the mean of the distribution, then you need to do some postprocessing. Using the relationship between and , can be written in terms of the parameters of the STWEEDIE model as

This shows that the parameters are identical for the mean and the scale model, and the base value of the mean model is

The estimate of and the standard error associated with it can be computed by using the property of the functions of maximum likelihood estimators (MLE). If represents a totally differentiable function of parameters , then the MLE of g has an asymptotic normal distribution with mean and covariance , where is the MLE of , is the estimate of covariance matrix of , and is the gradient vector of g with respect to evaluated at . For , the function is . The gradient vector is

You can write a DATA step that implements these computations by using the parameter and covariance estimates that the PROC SEVSELECT step prepares. The following statements show one such implementation:

/*--- Bring estimates data to the client ---*/
data estw;
   set mycas.estw;
run;

/*--- Compute the estimate, standard error, and p-value of the mean ---*/
data Mu0(keep=Parameter Estimate Stderr T probT);
   Parameter='Mu0';
   label Estimate='Estimate' Stderr='Standard;Error'
         T='t Value' probT='Approx;Pr > |t|';

   array cov{3,3} _temporary_;
   array parms{3} _temporary_;
   array parmrow{3} theta lambda p;
   set estw(where=(_MODEL_='Stweedie' and
                   (_type_='COV' or _type_='EST'))) end=eof;
   n = _n_-1;
   if (n = 0) then do;
      do i=1 to 3;
         parms[i] = parmrow[i];
      end;
   end;
   else do;
      do i=1 to n;
         cov[n,i] = parmrow[i];
      end;
   end;
   if (eof or n = 3) then do;
      mu0 = parms[1]*parms[2]*(2-parms[3])/(parms[3]-1);
      Estimate = mu0;

      a = mu0/parms[1]; /* dMu0_T0 */
      b = mu0/parms[2]; /* dMu0_L */
      c = -mu0/((parms[3]-1)*(2-parms[3])); /* dMu0_P */

      varMu0 = a * (a*cov[1,1]+b*cov[2,1]+c*cov[3,1]) +
               b * (a*cov[2,1]+b*cov[2,2]+c*cov[3,2]) +
               c * (a*cov[3,1]+b*cov[3,2]+c*cov[3,3]);

      Stderr = sqrt(varMu0);

      df = &samplesize-6;
      T = mu0/Stderr;
      probT = (1-probt(T, df))*2;
      output;
      stop;
   end;
run;

proc print data=Mu0 noobs s=';';
run;

The estimates of that the preceding DATA step prepares are shown in Output 23.3.3. These estimates and the estimates of as shown in Output 23.3.2 are reasonably close (that is, within one or two standard errors) to the parameters of the population from which the sample in mycas.Test_Sevtw data table was drawn.

Another outcome of using the scaled Tweedie distribution to model the influence of regression effects is that the regression effects also influence the variance V of the Tweedie distribution. The variance is related to the mean as , where is the dispersion parameter. Using the relationship between the parameters TWEEDIE and STWEEDIE distributions as described in the section Tweedie Distributions, the regression model for the dispersion parameter is

Subsequently, the regression model for the variance is

In summary, PROC SEVSELECT enables you to estimate regression effects on various parameters and statistics of the Tweedie model.