DEEPCAUSAL Procedure

This example illustrates how the DEEPCAUSAL procedure estimates the parameters of interest and performs policy evaluation and policy comparison. It also demonstrates how you can save the model information and use it later to score other new data. A simulated data set is generated, based on the following assumptions:

The outcome model is given as

where denotes the indices of the four covariates that are randomly selected from the 20 covariates and denotes the covariates vector .

The propensity score model is given as

where T denotes the treatment variable.

The following statements simulate samples that are based on the propensity score and outcome models that were just presented:

%macro deepEconGenerateData(n,d,eff,seed);
   data deepEconDGP;
      array x[&d.] x1-x&d.;
      array w[&d.] w1-w&d.;
      array selectedX[&eff.] selectedX1-selectedX&eff.;
      retain w;
      call streaminit('pcg', &seed.);
      * weights;
      sumw = 0;
      do i = 1 to &eff.;
         w[i] = rand('Uniform');
         sumw = sumw + w[i];
      end;
      do i = 1 to &eff.;
         w[i] = w[i] / sumw;
      end;
      * select x;
      do i = 1 to &eff.;
         selectedX[i] = ceil(&d.*rand('Uniform'));
      end;
      do i = 1 to &n.;
         * covariates;
         do j = 1 to &d.;
            x[j] = rand('Uniform');
         end;
         * treatment assignment;
         u = rand('Uniform');
         sumx = 0;
         do j = 1 to &eff.;
            sumx  = sumx  + w[j]*x[selectedX[j]];
         end;
         px = (0.1 + 0.8*sin(2*abs(x[selectedX[1]]-0.5)*3.1415926));
         if(u<=px) then t=1;
         else t=0;
         * outcome;
         eps = rand('Normal');
         mu = 1 + cos(sumx*2*3.1415926);
         tau = sin(sumx*2*3.1415926);
         y = mu + tau*t + eps;
         s1=(tau>0);
         s0=1-s1;
         output;
      end;
   run;
%mend;

%let n=20000;
%let d=20;
%let eff=4;
%let seed=12346;
%deepEconGenerateData(&n.,&d.,&eff.,&seed.);

The following DATA steps load the first observations in the data set deepEconDGP into the data table simCausal_train and the second observations into the data table simCausal_test in your session that is associated with the mylib libref. The DATA step assumes that your libref is named mylib, but you can substitute any appropriately defined libref.

data mylib.simCausal_train;
   set deepEconDGP(obs=10000 keep=i x1-x20 t y px mu tau s0 s1
                   selectedX1-selectedX4);
run;

data mylib.simCausal_test;
   set deepEconDGP(firstobs=10001 keep=i x1-x20 t y px mu tau s0 s1
                   selectedX1-selectedX4);
run;

The unknown functions , , and are estimated through two DNNs by using the data set simCausal_train. The parameters of interest, policy evaluation, and policy comparison are then estimated. The following statements use PROC DEEPCAUSAL to get these estimates and store the model information and parameter learning results:

proc deepcausal data=mylib.simCausal_train;
   id i;
   psmodel t=x1-x20 / dnn=(nodes=(32 32 32 32)
         train=(optimizer=(miniBatchSize=2000 regL1=0.0001 maxEpochs=1000
         algorithm=adam(learningRate=0.0001)) nthreads=5 seed=12345));
   model y=x1-x20 / dnn=(nodes=(32 32 32 32)
         train=(optimizer=(miniBatchSize=2000 regL1=0.001 maxEpochs=1000
         algorithm=adam) nthreads=5 seed=12345));
   infer policy=(s1 s0) policyComparison=(base=(t) compare=(s0 s1))
      out=mylib.oest outdetails=mylib.odetails;
   score outps=mylib.outpsdata outa=mylib.outadata outb=mylib.outbdata;
run;

The OUTPS= option writes the propensity score model information to the data table outpsdata, the OUTA= option writes the estimation information to the data table outadata, and the OUTB= option writes the estimation information to the data table outbdata. The number of observations is shown in Figure 1.

The estimates of parameters of interest are shown in Figure 2.

The policy evaluation estimates the expected utility of a policy. The policy evaluation results are shown in Figure 3.

The policy comparison estimates the difference in expected utility of two policies. The policy comparison results are shown in Figure 4.

You can apply the previously saved propensity score model, the estimation information, and the estimation information to a new data set by specifying the INPS=, INA=, and INB= options in the SCORE statement. The following statements use the outpsdata, outadata, and outbdata data tables as input data tables and estimate the parameters of interest, policy evaluation, and policy comparison by using the simCausal_test data set:

proc deepcausal data=mylib.simCausal_test;
   id i;
   infer policy=(s1 s0) policyComparison=(base=(t) compare=(s0 s1))
      out=mylib.oest2 outdetails=mylib.odetails2;
   score inps=mylib.outpsdata ina=mylib.outadata inb=mylib.outbdata;
run;

When you specify the INPS=, INA=, and INB= options in the SCORE statement, you do not need to specify the PSMODEL or MODEL statement. The estimates of parameters of interest, policy evaluation, and policy comparison are shown in Figure 5.

For more information about the estimates of parameters of interest, policy evaluation, and policy comparison, see the sections Full-Population Average Effect Parameters, Subpopulation Average Effect Parameters, and Policy Evaluation and Comparison.