The HPFENGINE Procedure

(View the complete code for this example.)

In its simplest usage, the HPFENGINE procedure produces results similar to those of the HPF procedure:

proc hpfengine data=sashelp.air
               print=(select summary);
   id date interval=month;
   forecast air;
run;

The GLOBALSELECTION= and REPOSITORY= options assume their respective default values. Therefore automatic selection is performed for the AIR series in SASHELP.AIR by using the models specified in the BEST selection list. The selection list BEST is found, together with the smoothing models it references, in SASHELP.HPFDFLT.

The results of the automatic model selection are displayed in Figure 1. A summary of the forecast is shown in Figure 2.

The first four models in the selection list are nonseasonal smoothing models. The HPFENGINE procedure determined that the series AIR in SASHELP.AIR was seasonal and attempted to fit only seasonal models.

The multiplicative Winters method produced a fit with the smallest root mean squared error (RMSE).

As another example, consider the problem of comparing the performance of multiple ARIMA models for a particular series. This is done by using the HPFARIMASPEC procedure as follows to specify the models.

proc hpfarimaspec repository=sasuser.repository
                  name=arima1;
   dependent symbol=air q=1
             diflist=(1 12) noint transform=log;
run;

proc hpfarimaspec repository=sasuser.repository
                  name=arima2;
   dependent symbol=air q=(1,12)
             diflist=(1 12) noint transform=log;
run;

The model specifications are grouped together in a selection list. Selection lists are built with the HPFSELECT procedure.

proc hpfselect repository=sasuser.repository
               name=myselect;
   spec arima1 arima2;
run;

The HPFENGINE procedure uses the GLOBALSELECTION= option to reference the selection list that contains the two ARIMA models. Selection /results are shown in Figure 3, and the forecast plot is shown in Figure 4.

proc hpfengine data=sashelp.air
               repository=sasuser.repository
               globalselection=myselect
               print=(select forecasts)
               plot=forecasts;
   id date interval=month;
   forecast air;
run;