Optimization Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 3, Shared Concepts (SAS Optimization: Mathematical Optimization Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example illustrates how you can use the solveLp action to solve linear programs. Suppose you want to solve the following problem:

The following DATA step creates the corresponding MPS-format data table. The DATA step assumes that your CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.example;
   input _id_ field1 $ field2 $ field3 $ field4 field5 $ field6;
   datalines;
1  NAME        .      EXAMPLE   .    .     .
2  ROWS        .      .         .    .     .
3  N           COST   .         .    .     .
4  G           R1     .         .    .     .
5  L           R2     .         .    .     .
6  L           R3     .         .    .     .
7  COLUMNS     .      .         .    .     .
8  .           X1     COST      2    R2    1
9  .           X1     R3        1    .     .
10 .           X2     COST     -3    R1   -2
11 .           X2     R2        1    R3    2
12 .           X3     COST     -4    R1   -3
13 .           X3     R2        2    R3    3
14 RHS         .      .         .    .     .
15 .           RHS    R1       -5    R2    4
16 .           RHS    R3        7    .     .
17 ENDATA      .      .         .    .     .
;

Alternatively, you can use the upload action on a CSV file that has the following content:

_id_ ,field1  ,field2 ,field3  ,field4 ,field5 ,field6
1    ,NAME    ,       ,EXAMPLE ,       ,       ,
2    ,ROWS    ,       ,        ,       ,       ,
3    ,N       ,COST   ,        ,       ,       ,
4    ,G       ,R1     ,        ,       ,       ,
5    ,L       ,R2     ,        ,       ,       ,
6    ,L       ,R3     ,        ,       ,       ,
7    ,COLUMNS ,       ,        ,       ,       ,
8    ,        ,X1     ,COST    ,2      ,R2     ,1
9    ,        ,X1     ,R3      ,1      ,       ,
10   ,        ,X2     ,COST    ,-3     ,R1     ,-2
11   ,        ,X2     ,R2      ,1      ,R3     ,2
12   ,        ,X3     ,COST    ,-4     ,R1     ,-3
13   ,        ,X3     ,R2      ,2      ,R3     ,3
14   ,RHS     ,       ,        ,       ,       ,
15   ,        ,RHS    ,R1      ,-5     ,R2     ,4
16   ,        ,RHS    ,R3      ,7      ,       ,
17   ,ENDATA  ,       ,        ,       ,       ,

You can use the following call to PROC CAS to solve the linear programming (LP) problem:

proc cas;
   loadactionset "optimization";
   action optimization.solveLp result=r status=s /
      data      = {name="example"}
      primalOut = {name="expout" replace=true}
      dualOut   = {name="exdout" replace=true}
      objSense  = "min"
      algorithm = "primal"
      logFreq   = 1;
   run;
   print r.SolutionSummary; run;
   action table.fetch / table = "expout"; run;
quit;

The primal solution is displayed in Output 2.12.1.

The progress of the solution is printed to the log, as shown in Output 2.12.2.

Note that the PRINT statement immediately after the call to the solveLp action prints the value of the SolutionSummary results table to the log, as shown in Output 2.12.3.