GAMSELECT Procedure

(View the complete code for this example.)

The Sashelp.JunkMail data set comes from a study that classifies whether an email is junk email (coded as 1) or not (coded as 0). The data were collected by Hewlett-Packard Labs and donated by George Forman. The data table, which is specified in the following DATA step, contains 4,601 observations, with 2 binary variables and 57 continuous explanatory variables. The response variable, Class, is a binary indicator of whether an email is considered spam or not. The partitioning variable, Test, is a binary indicator that is used to divide the data into training and testing parts. The 57 explanatory variables are continuous variables that represent frequencies of some common words and characters and lengths of uninterrupted sequences of capital letters in emails.

data mylib.JunkMail;
   set Sashelp.JunkMail;
run;

In the following program, the PARTITION statement divides the data into two parts. The training data have a Test value of 0 and contain about two-thirds of the data; the rest of the data are used to evaluate the fit. The macro function SplineVList is defined to specify spline terms by using the default construction.

%macro SplineVList(vars);
   %let i = 1;
   %do %while (%length(%scan(&vars,&i)));
      spline(%scan(&vars,&i))
      %let i = %eval(&i + 1);
   %end;
%mend;

proc gamselect data=mylib.JunkMail;
   model Class(event='1')= %SplineVList(Make Address All _3d Our Over Remove
         Internet Order Mail Receive Will People Report Addresses Free Business
         Email You Credit Your Font _000 Money HP HPL George _650 Lab Labs
         Telnet _857 Data _415 _85 Technology _1999 Parts PM Direct CS Meeting
         Original Project RE Edu Table Conference Semicolon Paren Bracket
         Exclamation Dollar Pound CapAvg CapLong CapTotal)
   / dist=binary allobs;
   partition rolevar=Test(train='0' test='1');
   selection method=boosting(maxIter=2000);
run;

The ALLOBS option specifies that all observations be used to construct the spline basis functions. By default, only observations that have the training data role are used to construct the spline basis functions. By default, observations with the validation or test role that have spline variable values outside the range of values that is used to construct the spline basis functions are omitted from the analysis.

The "Number of Observations" and "Response Profile" tables in Output 13.1.1 are divided into training and testing columns.

The "Iteration Summary" table in Output 13.1.2 shows that the boosting algorithm executed 2,000 iterations and selected the model that corresponds to the final iteration with 26 effects.

The fit statistics for the selected model are displayed in the "Fit Statistics" table in Output 13.1.3.

These statistics are computed for both the training and testing data. The average square error (ASE) and the misclassification rate should be similar between the two groups when the training data are representative of the testing data; for this model, the values of these statistics seem similar between the two disjoint subsets.

The "Selected Effects" table in Output 13.1.4 shows the effects that are included in the selected model, the iteration at which the effect first entered the model, and the number of iterations at which the effect was selected for an update.

For comparison, the following program uses PROC LOGSELECT to fit a parametric model by using forward selection and the same set of independent variables:

proc logselect data=mylib.JunkMail;
   model Class(event='1')=Make Address All _3d Our Over Remove Internet Order
         Mail Receive Will People Report Addresses Free Business Email You
         Credit Your Font _000 Money HP HPL George _650 Lab Labs Telnet _857
         Data _415 _85 Technology _1999 Parts PM Direct CS Meeting Original
         Project RE Edu Table Conference Semicolon Paren Bracket Exclamation
         Dollar Pound CapAvg CapLong CapTotal;
   partition rolevar=Test(train='0' test='1');
   selection method=forward;
run;

The "Selected Effects" table in Output 13.1.5 displays the 24 effects in the model that is selected by PROC LOGSELECT. The models that are selected by PROC GAMSELECT and PROC LOGSELECT have 22 variables in common.

The "Fit Statistics" table for the model that PROC LOGSELECT fits is shown in Output 13.1.6. The ASE and misclassification rates for both the training and test data are smaller for the model that PROC GAMSELECT fits (Output 13.1.3).