LOGSELECT Procedure

(View the complete code for this example.)

The Sashelp.JunkMail data set from Example 18.3 is used here to show how to store a model and later how to restore that same model for further processing. The following program fits a model by using a SELECTION statement, then stores the model by using a STORE statement. The NOTE= option in the STORE statement stores a few notes along with the model; you might also want to store the submitted program. The DISPLAY statement suppresses all output.

data mylib.JunkMail;
   set Sashelp.JunkMail;
run;

proc logselect data=mylib.JunkMail;
   model Class(event='1')=Make Address All _3d Our Over Remove Internet Order
         Mail Receive Will People Report Addresses Free Business Email You
         Credit Your Font _000 Money HP HPL George _650 Lab Labs Telnet _857
         Data _415 _85 Technology _1999 Parts PM Direct CS Meeting Original
         Project RE Edu Table Conference Semicolon Paren Bracket Exclamation
         Dollar Pound CapAvg CapLong CapTotal;
   display / excludeall;
   selection method=forward(maxstep=5);
   store mylib.mymodel /
         note="Generated with stepwise selection.";
run;

The following program replays the standard tables from the fitted model. You can also specify the STB, CLB, CORRB, COVB, and TYPE3 options and the CODE and ODDSRATIO statements, because they do not require access to data.

proc logselect restore=mylib.mymodel stb clb corrb covb type3;
   code;
   oddsratio;
run;

Information about the item store is displayed in Output 18.7.1. The Replay section is displayed in Output 18.7.2 through Output 18.7.5.

The standard tables from PROC LOGSELECT are displayed next, beginning with the "Model Information" table in Output 18.7.2.

The fit statistics shown in Output 18.7.4 are those that are computed when the original model is fit. If you specify the PARTFIT option or a PARTITION statement when the original model is fit, then this table always includes the additional statistics. However, specifying a PARTFIT option when you restore the model does not include the additional statistics in this table in the Replay section. Instead, the same table that appears in the Restore section is expanded; see Output 18.7.8.

If you specify the CTABLE, LACKFIT, ASSOCIATION, or PARTFIT option or the OUTPUT statement, then you must also specify an input data table. The following program requests these tables; the Replay section tables are produced but not displayed here.

proc logselect restore=mylib.mymodel data=mylib.JunkMail
   association ctable(cutpt=0.1 to 0.9 by 0.1) lackfit partfit;
   output out=mylib.out p cbar;
proc print data=mylib.out(obs=1);
run;

The first table that is displayed in the Restore section (Output 18.7.8) is the "Postfit Information" table, which contains the name of the input data table and information usually displayed in an "NObs" table. The next two tables are the "Response Profile" and "Fit Statistics" tables, which are computed from the JunkMail data.

The "Association" and "Classification" tables in Output 18.7.9 also provide information that is computed from the input data table.

The two Hosmer-Lemeshow tables whose content is computed from the input data are shown in Output 18.7.10.

The first line of the output data table is displayed in Output 18.7.11. Note that the CBAR statistic is not produced because the computation requires the original input data table.

You can specify the FITDATA option to indicate that the DATA= table is the original input table so that computation of the CBAR statistic is valid. The first observation in the output data table is shown in Output 18.7.12 and displays the CBAR statistic.

proc logselect restore=mylib.mymodel data=mylib.JunkMail fitdata;
   output out=mylib.out p cbar;
proc print data=mylib.out(obs=1);
run;