The QUANTLIFE Procedure

(View the complete code for this example.)

This example illustrates how to use quantile regression analysis to detect varying covariate effects on survival time. Consider a study of primary biliary cirrhosis, a rare but fatal chronic liver disease, discussed by Fleming and Harrington (1991). Researchers followed 418 patients who had this disease, 161 of whom died during the study.

The data set contains the following variables:

The following statements create the data set PBC, which is used in this example:

data pbc;
   input Time Status Age Albumin Bilirubin Edema Protime @@;
   label Time="Follow-Up Time in Days";
   logAlbumin   = log(Albumin);
   logBilirubin = log(Bilirubin);
   logProtime   = log(Protime);
   datalines;
  400 1 58.7652 2.60 14.5 1.0 12.2 4500 0 56.4463 4.14  1.1 0.0 10.6
 1012 1 70.0726 3.48  1.4 0.5 12.0 1925 1 54.7406 2.54  1.8 0.5 10.3
 1504 0 38.1054 3.53  3.4 0.0 10.9 2503 1 66.2587 3.98  0.8 0.0 11.0
 1832 0 55.5346 4.09  1.0 0.0  9.7 2466 1 53.0568 4.00  0.3 0.0 11.0
 2400 1 42.5079 3.08  3.2 0.0 11.0   51 1 70.5599 2.74 12.6 1.0 11.5
 3762 1 53.7139 4.16  1.4 0.0 12.0  304 1 59.1376 3.52  3.6 0.0 13.6

   ... more lines ...   

  989 0 35.0000 3.23  0.7 0.0 10.8  681 1 67.0000 2.96  1.2 0.0 10.9
 1103 0 39.0000 3.83  0.9 0.0 11.2 1055 0 57.0000 3.42  1.6 0.0  9.9
  691 0 58.0000 3.75  0.8 0.0 10.4  976 0 53.0000 3.29  0.7 0.0 10.6
;

The next statements fit a linear model for the log of survival time of the PBC patients with the covariates logBilirubin, logProtime, logAlbumin, Age, and Edema:

ods graphics on;
proc quantlife data=pbc log method=na plot=(quantplot survival) seed=1268;
   model Time*Status(0)=logBilirubin logProtime logAlbumin Age Edema
                        /quantile=(.1 .2 .3 .4 .5 .6 .75);
run;

You use the QUANTILE= option to specify a set of quantiles of interest for comparing quantile-specific covariate effects. The METHOD= option specifies the Nelson-Aalen method for estimating the regression parameters.

The QUANTLIFE procedure provides resampling methods for computing confidence limits for the parameters; for more information, see the section Confidence Interval. By default, the repetition number is 200. You can request a different number of repetitions by specifying the NREP= option. You can also use the SEED= option to specify the seed for generating random numbers so that you can later reproduce the results.

Output 96.1.1 displays model information and information about censoring in the data. Out of 418 observations, 257 are censored.

Output 96.1.2 provides the parameter estimates. Each quantile level has a set of parameter estimates and confidence limits.

For comparison, the following statements use the LIFEREG procedure to fit a Weibull distribution to the data. The LIFEREG procedure fits an accelerated failure time model, which assumes that the independent variables have a multiplicative effect on the event time.

proc lifereg data=pbc;
   model Time*Status(0)=logBilirubin logProtime logAlbumin Age Edema;
run;

Output 96.1.3 provides the parameter estimates that are computed by PROC LIFEREG.

The p-value for logProtime is very small. For this same variable, the p-values that result from the quantile regression analysis are 0.3148 for the 0.5th quantile and 0.4338 for the 0.75th quantile, and the p-values are much smaller for the lower quantiles. Apparently, the effect of this covariate depends on which side of the response distribution is being modeled.

The PLOT=QUANTPLOT option in the PROC QUANTLIFE statement requests the quantile process plots in Output 96.1.4, which plot the estimated regression parameter against the quantile level. You can use these plots to compare quantile-specific covariate effects. If the curve is not constant, it can indicate heterogeneity in the data. The interpretation of the regression coefficients at a given quantile is similar to that of classical regression analysis. That is, the coefficient from a given covariate indicates the effect on log(Time) of a unit change in that covariate, assuming that the other covariates are fixed.

In Output 96.1.4, you can see that the effect of logProtime has a negative effect over the lower quantiles, which diminishes in magnitude at the median and upper quantiles. This insight would be missed if you were using the accelerated failure model.

Output 96.1.4: Quantile Processes with 95% Confidence Bands