Statistical Graphics Using ODS

You can examine the underlying ODS data object to better understand how PROC SGPLOT constructs the fit functions. The following step creates the plot, this time creating an ODS data set:

proc sgplot data=sashelp.gas;
   ods output sgplot=sg;
   pbspline y=nox x=eqratio / group=fuel smooth=0 nknots=5
                              markerattrs=(size=3px) name='a';
   keylegend 'a' / location=inside position=topright across=1;
run;

The next steps create and display a subset of the data:

data subset(drop=SORT_FUEL_RETAIN_ALL_);
   set sg;
   Obs = _n_;
   by PBSPLINE_EQRATIO_NOX_GROUP_S__GP fuel;
   if _N_ gt 169 then do; fuel = '_'; eqratio = ._; nox = ._; end;
   if first.fuel or last.fuel or first.PBSPLINE_EQRATIO_NOX_GROUP_S__GP or
      last.PBSPLINE_EQRATIO_NOX_GROUP_S__GP or obs = 169 then output;
   if lag(first.fuel) or lag(first.PBSPLINE_EQRATIO_NOX_GROUP_S__GP) then do;
      call missing(of PBSPLI: Fuel EqRatio NOx obs);
      if _n_ gt 169 then do; fuel = '_'; eqratio = ._; nox = ._; end;
      output; output; output;
   end;
run;

proc print noobs; id obs; run;

The results are shown in Output 24.6.13.

Observations at the beginning and end of data groups are displayed. Missing values (ellipses) are displayed for other values. The first 169 observations contain the scatter plot variables Fuel, EqRatio, and NOx. After that, underscores indicate that those values are ignored. In the actual data set, which is too large to print in this example, observations 170 and beyond are excluded from the scatter plot because of missing values. All observations contain interpolated coordinates for the six fit functions. The manufactured variable PBSPLINE_EQRATIO_NOX_GROUP_S__GP contains 201 copies of each of the six fuel values. The other manufactured variables, PBSPLINE_EQRATIO_NOX_GROUP_S___X and PBSPLINE_EQRATIO_NOX_GROUP_S___Y, provide the X and Y coordinates, respectively, for the curve for each fuel group.

The results of the following step (which are not shown) show that 82rongas has only nine values:

proc freq data=sashelp.gas(where=(n(eqratio, nox) eq 2));
   tables fuel;
run;

Interpolation creates 201 interpolated values (200 line segments) from the minimum to the maximum by (maximum – minimum) / 200. You can specify the MAXPOINTS= option in the REG and PBSPLINE statements to change the number of interpolated values. Interpolation enables splines like the ones in Output 24.6.6 and Output 24.6.12—splines that have too many knots and too few values—to vary substantially from the original data. The automatic smoothing in penalized B-splines often prevents this variation from happening, but not always. In most cases, it is good that ODS Graphics automatically interpolates, but not always. In the next section, you will see examples that do not use interpolation.