The Network Action Set

This section contains PROC CAS code.

Note: Input data must be in a CAS table that is accessible in your CAS session. This table has a two-level name; the first level is your CAS engine libref and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 3: Shared Concepts in SAS Visual Data Mining and Machine Learning 8.3: Procedures Guide. For more information about PROC CAS and programming in CASL, see Getting Started with CASL, SAS Cloud Analytic Services: CAS Procedure Programming Guide and Reference, and SAS Viya: System Programming Guide.

This example illustrates the use of the biconnected components algorithm on the simple undirected graph G shown in Figure 16.1.

Figure 1: A Simple Undirected Graph G

The undirected graph G can be represented by the following links data set, LinkSetIn:

data LinkSetIn;
   input from $ to $ @@;
   datalines;
A B  A F  A G  B C  B D
B E  C D  E F  G I  G H
H I
;

The following DATA step loads the LinkSetIn data set into a CAS data table named mycas.LinkSetIn. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.LinkSetIn;
   set LinkSetIn;
run;

The following statements calculate the biconnected components and articulation points for G and output the results in the data tables LinkSetOut and NodeSetOut:

proc cas;
   loadactionset "network";
   action network.biconnectedComponents result=r status=s /
      indexOffset = 1
      links       = {name = "LinkSetIn"}
      outNodes    = {name = "NodeSetOut", replace="true"}
      outLinks    = {name = "LinkSetOut", replace="true"};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "LinkSetOut" sortBy = "biconcomp"; run;
   action table.fetch / table = "NodeSetOut"; run;
quit;

The problem summary output from this action is presented in Output 16.1.1.

The solution summary output from this action is presented in Output 16.1.2.

The output data table LinkSetOut contains the biconnected components of the input graph, as shown in Output 16.1.3.

The output data table NodeSetOut contains the articulation points of the input graph, as shown in Output 16.1.4.

The biconnected components are shown graphically in Output 16.1.5 and Output 16.1.6.