The Network Action Set

This section contains PROC CAS code.

Note: Input data must be in a CAS table that is accessible in your CAS session. This table has a two-level name; the first level is your CAS engine libref and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 3: Shared Concepts in SAS Visual Data Mining and Machine Learning 8.3: Procedures Guide. For more information about PROC CAS and programming in CASL, see Getting Started with CASL, SAS Cloud Analytic Services: CAS Procedure Programming Guide and Reference, and SAS Viya: System Programming Guide.

This section illustrates the use of the reach action on the simple directed graph G shown in Figure 16.12.

Figure 12: A Simple Directed Graph G

The directed graph G can be represented using the following links data set, LinkSetIn:

data LinkSetIn;
   input from $ to $ @@;
   datalines;
A B  A C  A D  B C  B E
B F  C E  D E  E D  E F
F G  G H  G I  H G  H I
;

Consider two sets of source nodes, and . These source node sets can be defined together as follows:

data NodeSubSetIn;
   input node $ reach;
   datalines;
A 2
C 1
H 2
;

The following DATA steps load the LinkSetIn and NodeSubSetIn data sets into CAS data tables named mycas.LinkSetIn and mycas.NodeSubSetIn. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.LinkSetIn;
   set LinkSetIn;
run;
data mycas.NodeSubSetIn;
   set NodeSubSetIn;
run;

You can use the following statements to find the reach network that is restricted by a hop limit of 1 from both sets of source nodes:

proc cas;
   loadactionset "network";
   action reach result=r status=s /
      direction     = "directed"
      links         = {name = "LinkSetIn"}
      nodessubset   = {name = "NodeSubSetIn"}
      outReachNodes = {name = "ReachNodes", replace=true}
      outReachlinks = {name = "ReachLinks", replace=true}
      outCounts     = {name = "ReachCounts", replace=true}
      maxreach      = 1;
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "ReachNodes" sortBy = "reach"; run;
   action table.fetch / table = "ReachLinks" sortBy = "reach"; run;
   action table.fetch / table = "ReachCounts" sortBy = "reach"; run;
quit;

The problem summary output from this action is presented in Output 16.11.1.

The solution summary output from this action is presented in Output 16.11.2.

The output data tables ReachNodes, ReachLinks, and ReachCounts now contain the nodes, links, and counts of the reach networks, respectively, that come from and . They are shown in Output 16.11.3 through Output 16.11.5.