The Network Action Set

This section contains PROC CAS code.

Note: Input data must be in a CAS table that is accessible in your CAS session. This table has a two-level name; the first level is your CAS engine libref and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 3: Shared Concepts in SAS Visual Data Mining and Machine Learning 8.3: Procedures Guide. For more information about PROC CAS and programming in CASL, see Getting Started with CASL, SAS Cloud Analytic Services: CAS Procedure Programming Guide and Reference, and SAS Viya: System Programming Guide.

This section provides a simple example of calculating node similarity in the undirected graph G that is shown in Figure 16.9.

Figure 9: A Simple Undirected Graph G

The undirected graph G can be represented by the links data set, LinkSetIn, that is created by the following DATA step:

data LinkSetIn;
   input from $ to $ weight;
   datalines;
A B 1
A D 1
C B 1
C D 1
E B 1
E D 1
E F 1
;

The following DATA step loads the LinkSetIn data set into a CAS data table named mycas.LinkSetIn. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.LinkSetIn;
   set LinkSetIn;
run;

The following statements find all node pairs that have a similarity score greater than or equal to 0.7:

proc cas;
   loadactionset "network";
   action nodeSimilarity result=r status=s /
      links          = {name = "LinkSetIn"}
      vector         = true
      nDimensions    = 10
      proximityOrder = "second"
      minScore       = 0.7
      outSimilarity  = {name = "NodeSim", replace=true};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "NodeSim" sortBy = {"source","sink"}; run;
quit;

The problem summary output from this action is presented in Output 16.8.1.

The solution summary output from this action is presented in Output 16.8.2.

The output data table NodeSim, as shown in Output 16.8.3, contains the pairs of nodes that have either a Jaccard or vector similarity score at or above the specified minScore parameter value of 0.7.

This example illustrates the intuition behind node similarity values. The nodes A and C have the same set of nearest neighbors (see Figure 16.9), B and D, resulting in the Jaccard similarity score of 1 and a vector similarity score very close to 1; thus the (A,C) pair is present in the output. The pair (B,F) appears in the output because the vector similarity score is greater than 0.7, whereas the Jaccard similarity score is lower than the minScore parameter threhold value. In this case, although B and F share only one neighbor out of four total, they do have common neighbors of the nearest neighbors; this results in a greater vector similarity value but not in a greater value of Jaccard similarity, which captures only the similarity of nearest-neighbor structures.

The first-order proximity can be calculated by the following statements:

proc cas;
   loadactionset "network";
   action nodeSimilarity result=r status=s /
      links          = {name = "LinkSetIn"}
      jaccard        = false
      vector         = true
      nDimensions    = 10
      proximityOrder = "first"
      minScore       = 0.7
      outSimilarity  = {name = "NodeSim", replace=true}
      outNodes       = {name = "NodeVecs", replace=true};
   run;
   action table.fetch / table = "NodeSim" sortBy = {"source","sink"}; run;
   action table.fetch / table = "NodeVecs" sortBy = "node"; run;
quit;

The output data table NodeSim, as shown in Output 16.8.4, contains the pairs of nodes and similarity scores for the first-order proximity. The example also demonstrates the intuition behind similarity based on first-order proximity and how it is different from the Jaccard-based proximity and the vector for the second-order proximity. Intuitively, the first-order vector similarity value between the nodes that are directly connected is higher than the first-order vector similarity value between the nodes that are separated by a longer path in a graph, whereas the Jaccard similarity and second-order vector similarity values are higher between the nodes that share more neighbors. The first-order vector similarity is more closely related to results that are produced by label propagation community detection algorithms, in the sense that the pairs of nodes that have high first-order vector similarity scores between them can be placed in one community.

The output data table NodeVecs contains node-embedding vectors, as shown in Output 16.8.5.