The Network Action Set

This section contains PROC CAS code.

Note: Input data must be in a CAS table that is accessible in your CAS session. This table has a two-level name; the first level is your CAS engine libref and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 3: Shared Concepts in SAS Visual Data Mining and Machine Learning 8.3: Procedures Guide. For more information about PROC CAS and programming in CASL, see Getting Started with CASL, SAS Cloud Analytic Services: CAS Procedure Programming Guide and Reference, and SAS Viya: System Programming Guide.

This example illustrates the use of the shortest path algorithm for all source-sink pairs on the simple undirected graph G shown in Figure 16.14.

Figure 14: A Simple Undirected Graph G

The undirected graph G can be represented by the following links data set, LinkSetIn:

data LinkSetIn;
   input from $ to $ weight @@;
   datalines;
A B 3  A C 2  A D 6  A E 4  B D 5
B F 5  C E 1  D E 2  D F 1  E F 4
;

The following DATA step loads the LinkSetIn data set into a CAS data table named mycas.LinkSetIn. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.LinkSetIn;
   set LinkSetIn;
run;

The following statements find the shortest paths for all source-sink pairs:

proc cas;
   loadactionset "network";
   action network.shortestPath result=r status=s /
      indexOffset = 1
      links       = {name = "LinkSetIn"}
      outWeights  = {name = "ShortPathW", replace=true}
      outPaths    = {name = "ShortPathP", replace=true};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table  = "ShortPathP" to=1000
                        sortBy = {"source","sink","order"}; run;
   action table.fetch / table = "ShortPathW" to=1000; run;
quit;

The problem summary output from this action is presented in Output 16.13.1.

The solution summary output from this action is presented in Output 16.13.2.

The output data table ShortPathP contains the shortest paths, as shown in Output 16.13.3.

The output data table ShortPathW contains the path weights of the shortest paths of each source-sink pair, as shown in Output 16.13.4.